第六講：均線（選股）的基本形態

提示：K線的初步平均。(O+H+L+C*2)/5;　或　 (H+L+C*2)/4;　
　
一般認為：收盤價是最有說服力的和最有價值的,它是每天激烈爭奪的最后妥協。但也有人認為：收盤價固然重要,其他價格也是爭奪的產物。所以將全天的幾種價格因素都考慮進去更能反映每天的真實情況。

1、最簡單的指標線
（1）均價線　就是 移動平均線MA,“MA”表示的就是計算平均值。
MA1=MA（CLOSE,5）；5日平均線=（今天收盤價+昨天收盤價+.....--5天前的收盤價）/5；
MA2=MA（CLOSE,10）；10日平均線=（今天收盤價+昨天收盤價+......+10天前的收盤價）/10；
（2）均量線　均價線會了,照著葫蘆畫瓢,把收盤價CLOSE換成成交量VOL就行了！
例：MA1：MA（VOL,5）；
MA2：MA（VOL,10）；

2、再次平均　指將已有的均線（多條均線）相加后進行再平均。
MA1=MA（CLOSE,5）；
MA2=MA（CLOSE,10）；
(MA1+MA2)/2;

3、N日均線向上　（本題反映均線波浪式延伸過程中某階段的形態。）
AA:=MA(C,N);
BB:=REF(AA,1);
AA>BB
　
均線向下呢？　AA< BB 就可以了。
N日均線走平怎么表述？AA=BB

4、均線由下跌狀態剛剛轉為上升
AA:=MA(C,N);
   COUNT(AA<REF(AA,1),6)=5   //用來確認前5日處于下跌狀態
    AND AA>REF(AA,5)；

5、年線拐頭向上
A250:=MA(C,250);
REF(A250,1)<REF(A250,2) AND A250>REF(A250,1);

6、兩條均線交叉
股軟中專門設定了一條函數來描述兩條線交叉：CROSS（X,Y） ,此函數通用。
假如兩條均線一條名叫X,另外一條叫Y 　且（X＜Y）
CROSS（X,Y）表示X向上穿過了Y 　通稱：金叉
CROSS（Y,X）表示Y向上穿過了X 　通稱：死叉
特別提示：交叉有兩種,一種是向上交叉,另一種是向下交叉。如果要求向上交叉時,X線必須比前一天高,所以需要加上　X>REF(X,1) 。完整的表達式為：CROSS（X,Y）AND　 X>REF(X,1)
加餐：
上述交叉是不限制周期的,有時我們會感到交叉特別頻繁,如何取得他們較長時間交叉一次的數據呢,系統提供了另一個函數： LONGCROSS(X,Y,N) 兩條線維持N周期后交叉。如果N等于15,則X　Y兩條線超過15天后交叉有效,否則不輸出。

7、多次金叉（以常見的MACD指標為例）
（1）二次金叉
(COUNT(CROSS(DIF,DEA),20)=2 AND CROSS(DIF,DEA);
（2）二次死叉
COUNT(CROSS(DEA,DIF),20)=2 AND CROSS(DEA,DIF);
（3）0軸上二次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=2 AND CROSS(DIF,DEA) AND
DEA>0;
（4）0軸上三次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=3 AND CROSS(DIF,DEA) AND
DEA>0;

8、三線金叉
A5:=MA(C,5);
A10:=MA(C,10);
A30:=MA(C,30);
AA:=CROSS(A5,A10);
BB:=CROSS(A5,A30);
CC:=CROSS(A10,A30);
COUNT(AA,3)=1 AND COUNT(BB,3)=1 AND COUNT(CC,3)=1;

9、三線同時金叉
A5:=MA(C,5);
A10:=MA(C,10);
A20:=MA(C,20);
AA:=CROSS(C,A5);
BB:=CROSS(C,A10);
CC:=CROSS(C,A20);
AA AND BB AND CC;

10、均線多頭排列
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
A1>A2 AND A2>A3 AND A3>A4;

11、均線空頭排列3天以上
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
COUNT(A1< A2 AND A2< A3 AND A3< A4,3)>=3;

12、向前N日至M日出現過均線死叉（P1< P2）
AA:=MA(C,P1);
BB:=MA(C,P2);
CC:=REF(CROSS(BB,AA),N);
COUNT(CC,M);
　
13、均線粘合
MA1:=MA(C,5);
MA2:=MA(C10);
MA3:=MA(C,20);
P1:=ABS(MA1-MA2)+ABS(MA2-MA3);
P1/C<1/100 AND MA1>REF(MA1,1) AND MA2>REF(MA2,1);　

14、均線粘合（另種表達式）
MA1:=MA(C,5);
MA2:=MA(C,10);
MA3:=MA(C,30);
A:=MAX(MAX(MA1,MA2),MA3);
B:=MIN(MIN(MA1,MA2),MA3);
COUNT(ABS(A-B)/B<0.01,3)=3;表示已粘合3天（含3天）以上

15、多條均線粘合如5、10、20、30、120、250日移動平均線粘合
aa:=(ma(c,5)+ma(c,10)+ma(c,20)+ma(c,30)+ma(c,120)+ma(c,250))/6;
up:=aa*n/100+aa;
down:=aa-aa*n/100;
count(BETWEEN(ma(c,5),up,down) and BETWEEN(ma(c,10),up,down) and BETWEEN(ma(c,20),up,down) and BETWEEN(ma(c,30),up,down)and BETWEEN(ma(c,120),up,down) and BETWEEN(ma(c,250),up,down),m)=m;
    n（2,1,500） m（10,1,100） 調整參數n為粘合程度,n值越小粘合的程度越高,即均線距離越近；m為粘合周期。

16、乖離均線
BIAS1：（CLOSE-MA（CLOSE,N））/MA（CLOSE,N）*100；
當日股價與N日均線的乖離率=（當日股價-N日均價）/N日均價*100；　
特別提示：乖離均線是由乖離率的“點”連成的均線。 此線雖非普通均線,因常用,故單提出來。
原理：以當日的均線價格為準,股價和均價之間的差距稱為乖離程度,以乖離程度除以均價的百分比就是乖離率。